Actions

SCHG How-to

Use correct height when roll jumping

From Sonic Retro

Revision as of 11:11, 25 August 2018 by Black Squirrel (talk | contribs) (Text replacement - "\[\[Category:SCHG How-tos.*" to "")
(diff) ← Older revision | Latest revision (diff) | Newer revision → (diff)

(Original guide by MoDule) (S3K fix by ThomasSpeedrunner)

In every main series 16-bit Sonic game, there is a small bug in Sonic's jumping code that assigns him the wrong height and width when jumping while rolling on the ground. Most of the time this goes unnoticed, however occasionally when landing it will cause Sonic to be moved up too far, back into the air and make him temporarily unable to jump. This guide will show how to fix the bug and explain its origin.

Fixing the bug

Sonic 2, SVN disassembly

Locate the Sonic_Jump routine and comment out two lines as follows:

; loc_1AA38:
Sonic_Jump:
	move.b	(Ctrl_1_Press_Logical).w,d0
	andi.b	#button_B_mask|button_C_mask|button_A_mask,d0 ; is A, B or C pressed?
	beq.w	return_1AAE6	; if not, return

	[...]

	;move.b	#$13,y_radius(a0)	; set to standing height	;<-- the offending lines
	;move.b	#9,x_radius(a0)		; and width			;<--
	btst	#2,status(a0)	; is Sonic rolling?
	bne.s	Sonic_RollJump	; if yes, branch
	move.b	#$E,y_radius(a0)	; set to rolling height
	move.b	#7,x_radius(a0)		; and width
	move.b	#2,anim(a0)	; use "jumping" animation
	bset	#2,status(a0)
	addq.w	#5,y_pos(a0)
 
return_1AAE6:
	rts
; ---------------------------------------------------------------------------
; loc_1AAE8:
Sonic_RollJump:
	bset	#4,status(a0)	; set the rolling+jumping flag
	rts
; End of function Sonic_Jump

Sonic 3 & Knuckles, SVN disassembly

The routine to find here: Sonic_Jump:. For those who prefer using location-based labels, this is sub_117DA:. Scroll down until you see this or something like it (this has SSTs labeled to enhance readability):

		move.b	default_y_radius(a0),y_radius(a0)	; <-- This line
		move.b	default_x_radius(a0),x_radius(a0)	; <-- This line
		btst	#2,status(a0)
		bne.s	loc_118B4

Comment out or delete the indicated lines.

Things to keep in mind

This bug will be present in any other player objects as well, meaning it needs to be fixed for Tails and Knuckles if they exist, as well as any other characters you may have. Another small thing to note is that this reduces Sonic's hitbox when roll jumping. This shouldn't be much of a problem, though.

The bug explained

The normal procedure for when Sonic jumps is to change him into a ball, reduce his size and due to the height difference move him down a bit, as seen here:

	move.b	#$E,y_radius(a0)	; set to rolling height
	move.b	#7,x_radius(a0)		; and width
	move.b	#2,anim(a0)	; use "jumping" animation
	bset	#2,status(a0)
	addq.w	#5,y_pos(a0)	;<-- move to ground

S3K hackers, yours will look something like this:

		move.b	#$E,y_radius(a0)	; set to rolling height
		move.b	#7,x_radius(a0)		; set to rolling width
		move.b	#id_SonicRoll,anim(a0)	; use "jumping" animation
		bset	#2,status(a0)
		move.b	y_radius(a0),d0
		sub.b	default_y_radius(a0),d0
		ext.w	d0
		tst.b	(Reverse_gravity_flag).w
		beq.s	loc_118AE
		neg.w	d0

loc_118AE:
		sub.w	d0,y_pos(a0)		; <-- move to ground

The problem lies with the four lines above this code:

	move.b	#$13,y_radius(a0)	; set to standing height
	move.b	#9,x_radius(a0)		; and width
	btst	#2,status(a0)	; is Sonic rolling?
	bne.s	Sonic_RollJump	; if yes, branch

S3K hackers, yours will look something like this:

		move.b	default_y_radius(a0),y_radius(a0)
		move.b	default_x_radius(a0),x_radius(a0)
		btst	#2,status(a0)
		bne.s	loc_118B4

The last two lines make sense. If Sonic is already rolling his size and position should be correct, so the code underneath can be skipped. The other two lines would appear to reset Sonic to his normal size, something that doesn't make sense in this context. When jumping normally these two lines have no effect whatsoever, as they are undone shortly afterward. Unfortunately, the code that fixes this problem is skipped when Sonic is already rolling, and he ends up with the wrong height. Now, when he lands on the ground, this code runs:

; loc_1B0AC:
Sonic_ResetOnFloor_Part2:
	[...]

	btst	#2,status(a0)			; is Sonic rolling?
	beq.s	Sonic_ResetOnFloor_Part3	; if not, branch
	bclr	#2,status(a0)
	move.b	#$13,y_radius(a0) ; reset Sonic's size to standing
	move.b	#9,x_radius(a0)
	move.b	#AniIDSonAni_Walk,anim(a0)	; use running/walking/standing animation
	subq.w	#5,y_pos(a0)	;<-- move Sonic up 5 pixels so the increased height doesn't push him into the ground

What this code does, is reset Sonic to his normal standing height and move him up by 5 pixels when he is in a spinning state. This all makes sense, under the assumption that Sonic is actually using his rolling height. If he isn't, he'll end up 5 pixels in the air, which is exactly what happens when roll jumping.

SCHG How-To Guide: Sonic the Hedgehog 2 (16-bit)
Fixing Bugs
Fix Demo Playback | Fix a Race Condition with Pattern Load Cues | Fix Super Sonic Bugs | Use Correct Height When Roll Jumping | Fix Jump Height Bug When Exiting Water | Fix Screen Boundary Spin Dash Bug | Correct Drowning Bugs | Fix Camera Y Position for Tails | Fix Tails Subanimation Error | Fix Tails' Respawn Speeds | Fix Accidental Deletion of Scattered Rings | Fix Ring Timers | Fix Rexon Crash | Fix Monitor Collision Bug | Fix EHZ Deformation Bug | Correct CPZ Boss Attack Behavior | Fix Bug in ARZ Boss Arrow's Platform Behavior | Fix ARZ Boss Walking on Air Glitch | Fix ARZ Boss Sprite Behavior | Fix Multiple CNZ Boss Bugs | Fix HTZ Background Scrolling Mountains | Fix OOZ Launcher Speed Up Glitch | Fix DEZ Giant Mech Collision Glitch | Fix Boss Deconstruction Behavior | Fix Speed Bugs | Fix 14 Continues Cheat | Fix Debug Mode Crash | Fix 99+ Lives | Fix Sonic 2's Sega Screen
Design Choices
Remove the Air Speed Cap | Disable Floor Collision While Dying | Modify Super Sonic Transformation Methods & Behavior | Enable/Disable Tails in Certain Levels | Collide with Water After Being Hurt | Retain Rings When Returning at a Star Post | Improve the Fade In\Fade Out Progression Routines | Fix Scattered Rings' Underwater Physics | Insert LZ Water Ripple Effect | Restore Lost CPZ Boss Feature | Prevent SCZ Tornado Spin Dash Death | Improve ObjectMove Subroutines | Port S3K Rings Manager | Port S3K Object Manager | Port S3K Priority Manager | Edit Level Order with ASM‎ | Alter Ring Requirements in Special Stages | Make Special Stage Characters Use Normal DPLCs | Speed Up Ring Loss Process | Change spike behaviour in Sonic 2
Adding Features
Create Insta-kill and High Jump Monitors | Create Clone and Special Stage Monitors | Port Knuckles
Sound Features
Expand Music Index to Start at $00 | Port Sonic 1 Sound Driver | Port Sonic 2 Clone Driver | Port Sonic 3 Sound Driver | Port Flamewing's Sonic 3 & Knuckles Sound Driver | Expand the Music Index to Start at $00 (Sonic 2 Clone Driver Version) | Play Different Songs Per Act
Extending the Game
Extend the Level Index Past $10 | Extend the Level Select | Extend Water Tables | Add Extra Characters | Free Up 2 Universal SSTs


|Use correct height when roll jumping]]